Handy Shaman Macros

Macros are a handy way of adding a little extra logic to a spell or ability. They’re also a good way to save some space on your casting bars by combining buffs or spells that you use occasionally or out of combat. Most of these macros come from my shaman and are in use every time I play.

Attack

This macro automatically starts your normal attack after using Stormstrike. This is useful if you like to start your attacks with a Stormstrike. Fairely simple, but saves an extra step.

#showtooltip
/cast Stormstrike
/startattack

Weapon Enchants

Here is an example of a space-saving macro. It does something slightly different depending on the modifier being held down when you click on the macro. The macro casts Windfury Weapon with no modifier. If you hold down control when clicking, it casts Flametongue Weapon, and if you hold down shift, it casts Frostbrand Weapon. It also casts the spell on your main weapon if the left mouse button was used and on your off-hand weapon if the right mouse button was used.

/use [nomodifier] Windfury Weapon; [modifier:ctrl] Flametongue Weapon; [modifier:shift] Frostbrand Weapon
/use [button:1] 16; [button:2] 17

Elemental Shields

A similar macro to the above for Water Shield and Lightning Shield.

/use [nomodifier] Water Shield; [modifier:shift] Lightning Shield

Totems

This macro drops a predetermined set of totems in the order specified. It saves a little time especially if you find your self always dropping the same totems.

/castsequence reset=4 Grounding Totem, Tremor Totem, Mana Spring Totem, Grounding Totem, Searing Totem

You will need to hit the button four times (once for each totem).

Since the introduction of the new Totem Bar and Call of the Elements (and the other two similar spells) this macro has lots much of its use.

Healing

This is what I use for a healing macro. It heals the right target in a few different situations. First, if the alt key is down it will always cast the spell on yourself. Otherwise, if the target is friendly it will cast on them. If the target of the target is friendly it will cast on them, and if all else fails it will cast on you.

#showtooltip Lesser Healing Wave
/cast [modifier:alt,target=player] [target=target,help] [target=targettarget,help] [target=player] Lesser Healing Wave

You could include support for a mouse-over target.

#showtooltip Lesser Healing Wave
/cast [target=mouseover,help,exists] [target=target,help] [target=targettarget,help] [target=player] Lesser Healing Wave

I use this type of macro for all of my healing spells and even my cure spells. If you have Nature’s Swiftness this will give you a quick heal on yourself. Just remove the “[target=player]” part to cast on your current target.

/stopcasting
/cast Nature’s Swiftness
/cast [target=player] Healing Wave

If you have a trinket (or two) that you want to use before casting Healing Wave you can use this macro.

/stopcasting
/use 13
/use 14
/cast Nature’s Swiftness
/cast [target=player] Healing Wave

The number 13 and 14 are your top and bottom trinket slots (in that order).

Purge

This is what I use for my purge macro. It only adds a check that if your target or your target’s target is an enemy then cast Purge.

#showtooltip Purge
/cast [harm, nodead] [target=targettarget,harm,nodead] Purge

Spell Interrupt

Wind Shear is the new way to interrupt spell casting. Here’s a basic macro that stops any spell currently being cast by you and immediately casts Wind Shear on your target.

#showtooltip
/stopcasting
/cast Wind Shear

The macro that I use is a bit more complicated. If my focus target is an enemy then it casts Wind Shear on them. If my mouseover target is an enemy then it casts Wind Shear on them. Otherwise, it simply casts Wind Shear on my current target.

#showtooltip
/stopcasting
/cast [target=focus,harm,exists] Wind Shear
/cast [target=mouseover,harm,exists] Wind Shear
/cast Wind Shear

To set and clear your focus target you can use the /focus command.

Shield Swap

Here’s the macro I use for shield swap. I usually start arena matches with a shield equipped in case I get jumped by a rogue or charged by a warrior. I also try to wear by shield in battlegrounds when mounted.

#showtooltip [noequipped:shield] Merciless Gladiator’s Redoubt; Gladiator’s Cleaver
/equipslot [noequipped:shield] 17 Merciless Gladiator’s Redoubt
/equipslot [equipped:shield] 17 Gladiator’s Cleaver
/sctdisplay ‘Shield Swap’

The last line causes Scrolling Combat Text to display a message every time the macro runs. You’ll have to replace the name of your shield with Merciless Gladiator’s Redoubt and off-hand weapon with Gladiator’s Cleaver.

Reference

My main source of reference is the shaman macro page on WoWWiki. It has an excellent selection of macros for a variety of classes. Don’t forget to check out the macros for other classes. Some of them can come in handy for shaman too. This thread on the official forums also has some useful shaman macros.

Update 1: updated the section on interrupts to use the Wind Shear spell instead of the old Earth Shock for interrupts.